mozilla-central: dom/canvas/test/webgl-conf/checkout/conformance2/glsl3/array-in-complex-expression.html@8f464d9c468ba1a7c1b0338deaa8bc8023f8ae3d

<!--
Copyright (c) 2019 The Khronos Group Inc.
Use of this source code is governed by an MIT-style license that can be
found in the LICENSE.txt file.
-->

<!DOCTYPE html>
<html>
<head>
<meta charset="utf-8">
<title>GLSL array in complex expression test</title>
<link rel="stylesheet" href="../../resources/js-test-style.css"/>
<script src="../../js/js-test-pre.js"></script>
<script src="../../js/webgl-test-utils.js"></script>
<script src="../../js/glsl-conformance-test.js"></script>
</head>
<body>
<div id="description"></div>
<div id="console"></div>
<script id="fshaderAndShortCircuits" type="x-shader/x-fragment">#version 300 es
precision mediump float;

out vec4 my_FragColor;

int g = 0;

int[2] plus() {
    ++g;
    return int[2](g, g);
}

bool minus() {
    --g;
    return false;
}

void main() {
    int a[2] = int[2](0, 0);
    // The function call must not be evaluated, since && short-circuits
    minus() && (a == plus());
    my_FragColor = vec4(0.0, ((g == -1) ? 1.0 : 0.0), 0.0, 1.0);
}
</script>
<script id="fshaderOrShortCircuits" type="x-shader/x-fragment">#version 300 es
precision mediump float;

out vec4 my_FragColor;

int g = 0;

int[2] plus() {
    ++g;
    return int[2](g, g);
}

bool minus() {
    --g;
    return true;
}

void main() {
    int a[2] = int[2](0, 0);
    // The function call must not be evaluated, since || short-circuits.
    minus() || (a == plus());
    my_FragColor = vec4(0.0, ((g == -1) ? 1.0 : 0.0), 0.0, 1.0);
}
</script>
<script id="fshaderTernaryOnlyEvaluatesOneOperand" type="x-shader/x-fragment">#version 300 es
precision mediump float;

out vec4 my_FragColor;

int g = 0;

int[2] plus() {
    ++g;
    return int[2](g, g);
}

void main() {
    int a[2] = int[2](0, 0);
    // The function call must not be evaluated, since the condition is true.
    (g == 0) ? true : (a == plus());
    my_FragColor = vec4(0.0, ((g == 0) ? 1.0 : 0.0), 0.0, 1.0);
}
</script>
<script id="fshaderSequenceSideEffectsAffectingComparedArrayContent" type="x-shader/x-fragment">#version 300 es
precision mediump float;

out vec4 my_FragColor;

int[2] func(int param) {
    return int[2](param, param);
}

void main() {
    int a[2];
    for (int i = 0; i < 2; ++i) {
        a[i] = 1;
    }
    int j = 0;
    // Sequence operator evaluates operands from left to right (ESSL 3.00 section 5.9).
    // The function call that returns the array needs to be evaluated after ++j
    // for the expression to return the correct value (true).
    bool result = ((++j), (a == func(j)));
    my_FragColor = vec4(0.0, (result ? 1.0 : 0.0), 0.0, 1.0);
}
</script>
<script type="application/javascript">
"use strict";
description("Arrays in complex expressions should work");
debug("");
debug("This test is targeted to stress syntax tree transformations that might need to be done in shader translation when the platform doesn't natively support arrays as return values.");

GLSLConformanceTester.runRenderTests([
{
  fShaderId: 'fshaderAndShortCircuits',
  fShaderSuccess: true,
  linkSuccess: true,
  passMsg: "Expression where an array is returned from a function call inside an operand to && that doesn't get evaluated as result of short-circuiting"
},
{
  fShaderId: 'fshaderOrShortCircuits',
  fShaderSuccess: true,
  linkSuccess: true,
  passMsg: "Expression where an array is returned from a function call inside an operand to || that doesn't get evaluated as result of short-circuiting"
},
{
  fShaderId: 'fshaderTernaryOnlyEvaluatesOneOperand',
  fShaderSuccess: true,
  linkSuccess: true,
  passMsg: "Expression where an array is returned from a function call in an operand of a ternary operator that doesn't get evaluated"
},
{
  fShaderId: 'fshaderSequenceSideEffectsAffectingComparedArrayContent',
  fShaderSuccess: true,
  linkSuccess: true,
  passMsg: 'Expression where first operand of a sequence operator has side effects which affect the second operand that returns an array'
}
], 2);
</script>
</body>
</html>
author	Lando <lando@lando.test>
	Thu, 10 Jul 2025 16:11:40 +0000 (103 minutes ago)
changeset 795966	8f464d9c468ba1a7c1b0338deaa8bc8023f8ae3d
parent 515042	f3948e689af746c84af3a24b00e0a33762d15cf7
permissions	-rw-r--r--