dom/media/gmp/PChromiumCDM.ipdl
author Subhamoy Sengupta <ssengupta@mozilla.com>
Wed, 01 Jul 2020 13:07:41 +0000
changeset 3016298 1b42cfac254b2323214a07f3174a265f3e122be0
parent 2876894 1634aa932e28cc0e87db8c55f36d7d7d3b85f0d2
child 3018900 16c92f73e178c26d35c998aac18e24f366400c5b
permissions -rw-r--r--
Bug 1619953 - P1 - Added missing include in PChromiumCDM.ipdl r=baku Summary: This fix was required for subsequent patches to build successfully, because adding new source files exposed missing dependencies in unified sources. Differential Revision: https://phabricator.services.mozilla.com/D75290 Test Plan: Reviewers: baku Subscribers: Bug #: 1619953 Differential Diff: PHID-DIFF-s5dslytqzzcf4pxgnn23

/* -*- Mode: C++; tab-width: 2; indent-tabs-mode: nil; c-basic-offset: 2 -*- */
/* This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this
 * file, You can obtain one at http://mozilla.org/MPL/2.0/. */

include protocol PGMPContent;
include GMPTypes;

include "GMPMessageUtils.h";

using cdm::HdcpVersion from "content_decryption_module.h";

include "GMPMessageUtils.h";

namespace mozilla {
namespace gmp {

async refcounted protocol PChromiumCDM
{
  manager PGMPContent;
child:

  // cdm::ContentDecryptionModule_10
  async Init(bool aAllowDistinctiveIdentifier,
             bool aAllowPersistentState) returns (bool aSuccess);

  async GetStatusForPolicy(uint32_t aPromiseId,
                           HdcpVersion aMinHdcpVersion);

  async SetServerCertificate(uint32_t aPromiseId,
                             uint8_t[] aServerCert);

  async CreateSessionAndGenerateRequest(uint32_t aPromiseId,
                                        uint32_t aSessionType,
                                        uint32_t aInitDataType,
                                        uint8_t[] aInitData);

  async LoadSession(uint32_t aPromiseId,
                    uint32_t aSessionType,
                    nsCString aSessionId);

  async UpdateSession(uint32_t aPromiseId,
                      nsCString aSessionId,
                      uint8_t[] aResponse);

  async CloseSession(uint32_t aPromiseId,
                     nsCString aSessionId);

  async RemoveSession(uint32_t aPromiseId,
                      nsCString aSessionId);

  async Decrypt(uint32_t aId, CDMInputBuffer aBuffer);

  async InitializeVideoDecoder(CDMVideoDecoderConfig aConfig);

  async DeinitializeVideoDecoder();

  async ResetVideoDecoder();

  async DecryptAndDecodeFrame(CDMInputBuffer aBuffer);

  async Drain();

  async Destroy();

  async GiveBuffer(Shmem aShmem);

  async PurgeShmems();


parent:
  async __delete__();

  // cdm::Host_10
  async OnResolvePromiseWithKeyStatus(uint32_t aPromiseId, uint32_t aKeyStatus);

  async OnResolveNewSessionPromise(uint32_t aPromiseId, nsCString aSessionId);

  async OnResolvePromise(uint32_t aPromiseId);

  async OnRejectPromise(uint32_t aPromiseId,
                        uint32_t aException,
                        uint32_t aSystemCode,
                        nsCString aErrorMessage);

  async OnSessionMessage(nsCString aSessionId,
                         uint32_t aMessageType,
                         uint8_t[] aMessage);

  async OnSessionKeysChange(nsCString aSessionId,
                            CDMKeyInformation[] aKeysInfo);

  async OnExpirationChange(nsCString aSessionId,
                           double aSecondsSinceEpoch);

  async OnSessionClosed(nsCString aSessionId);

  async ResolveLoadSessionPromise(uint32_t aPromiseId, bool aSuccessful);

  // Return values of cdm::ContentDecryptionModule_10::Decrypt
  async Decrypted(uint32_t aId, uint32_t aStatus, Shmem aDecryptedData);
  async DecryptFailed(uint32_t aId, uint32_t aStatus);

  async OnDecoderInitDone(uint32_t aStatus);

  // Return values of cdm::ContentDecryptionModule_10::DecryptAndDecodeFrame
  async DecodedShmem(CDMVideoFrame aFrame, Shmem aData);
  async DecodedData(CDMVideoFrame aFrame, uint8_t[] aData);
  async DecodeFailed(uint32_t aStatus);

  async ResetVideoDecoderComplete();

  async DrainComplete();

  async Shutdown();

  async IncreaseShmemPoolSize();
};

} // namespace gmp
} // namespace mozilla