suite/configure.in
author Philipp Kewisch <mozilla@kewis.ch>
Sun, 26 Feb 2017 16:45:39 +0100
changeset 50099 917c4b2f3af1530cd2e3517b3b8454e659b638d9
parent 46355 7364d427246cc5712b0befd47ffff6e5eefc5372
permissions -rw-r--r--
WiP TODO -- make c-c a subdir under m-c MozReview-Commit-ID: DhZnUDM0EyZ

dnl -*- Mode: Autoconf; tab-width: 2; indent-tabs-mode: nil; -*-
dnl vi: set tabstop=2 shiftwidth=2 expandtab:
dnl This Source Code Form is subject to the terms of the Mozilla Public
dnl License, v. 2.0. If a copy of the MPL was not distributed with this
dnl file, You can obtain one at http://mozilla.org/MPL/2.0/.

dnl Things we need to carry from confvars.sh
AC_DEFINE(MOZ_SUITE)
AC_SUBST(MOZ_SUITE)
AC_SUBST(MOZ_COMPOSER)
AC_SUBST(SEAMONKEY_VERSION)
AC_DEFINE(MOZ_SEPARATE_MANIFEST_FOR_THEME_OVERRIDES)
AC_SUBST(MOZ_BUNDLED_FONTS)

dnl Set up variables based on if either the mozilla repo is the
dnl subdirectory or the comm repo.
if test "$MOZ_BUILD_APP" = "comm/suite"
then
  dnl we are building with comm/ as the subdirectory
  dnl $srcdir is the mozilla repo, comm is in the subdir
  moztopsrcdir=$srcdir
  commtopsrcdir=$srcdir/comm

  mozreltopsrcdir=.
  commreltopsrcdir=comm
else
  dnl we are building with mozilla/ as the subdirectory
  dnl $srcdir is still the mozilla repo, so use the parent for comm
  moztopsrcdir=$srcdir
  commtopsrcdir=$srcdir/..

  mozreltopsrcdir=mozilla
  commreltopsrcdir=.
fi
AC_SUBST(moztopsrcdir)
AC_SUBST(commtopsrcdir)
AC_SUBST(mozreltopsrcdir)
AC_SUBST(commreltopsrcdir)

dnl Optional parts of the build.
AC_SUBST(MOZ_MORK)
if test "$MOZ_MORK"; then
  AC_DEFINE(MOZ_MORK)
fi
if test "$OS_ARCH" != "WINNT"; then
  MOZ_MOVEMAIL=1
  HAVE_MOVEMAIL=1
  AC_DEFINE(HAVE_MOVEMAIL)
fi
AC_SUBST(MOZ_MOVEMAIL)

dnl Get other versions (for the calendar plugin)
THUNDERBIRD_VERSION=`cat ${_topsrcdir}/../mail/config/version.txt`
AC_SUBST(THUNDERBIRD_VERSION)

dnl =========================================================
dnl = Lightning extension
dnl =========================================================
MOZ_ARG_ENABLE_BOOL(calendar,
[  --enable-calendar      Enable building of the Lightning calendar extension],
    MOZ_CALENDAR=1,
    MOZ_CALENDAR= )
AC_SUBST(MOZ_CALENDAR)

dnl =========================================================
dnl = LDAP
dnl =========================================================
MOZ_ARG_DISABLE_BOOL(ldap,
[  --disable-ldap          Disable LDAP support],
    MOZ_LDAP_XPCOM=,
    MOZ_LDAP_XPCOM=1)

AC_SUBST(MOZ_LDAP_XPCOM)

dnl =========================================================
dnl = MAPI support (Windows only)
dnl =========================================================

if test "$_WIN32_MSVC"; then
    MOZ_MAPI_SUPPORT=1
fi

MOZ_ARG_DISABLE_BOOL(mapi,
[  --disable-mapi          Disable MAPI support],
    MOZ_MAPI_SUPPORT= )

AC_SUBST(MOZ_MAPI_SUPPORT)

if test -n "$MOZ_MAPI_SUPPORT"; then
    AC_DEFINE(MOZ_MAPI_SUPPORT)
fi