layout/ipc/PRenderFrame.ipdl
author Peter Van der Beken <peterv@propagandism.org>
Fri, 24 Aug 2012 09:32:26 -0700
changeset 109357 dc3f29a730b10ace9129d2605c7a40822ee8121f
parent 107894 282bfd3e56e029cc430ac372a7cdcaa660586e1f
child 122853 09eab2b9e96a0b7ea4f741b752503a583d3bab3d
permissions -rw-r--r--
Bug 753517 part 5. Enable the list IC for new DOM bindings too. r=bz.

/* -*- Mode: C++; tab-width: 8; indent-tabs-mode: nil; c-basic-offset: 2 -*-
 * vim: sw=2 ts=8 et :
 */
/* This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this
 * file, You can obtain one at http://mozilla.org/MPL/2.0/. */

include protocol PBrowser;
include protocol PLayers;

namespace mozilla {
namespace layout {

/**
 * PRenderFrame (in the layout sense of "frame") represents one web
 * "page".  It's used to graft content processes' layer trees into
 * chrome's rendering path.  The lifetime of a PRenderFrame is tied to
 * its PresShell in the child process.
 *
 * The child process conceptually "owns" a PRenderFrame, because it
 * only makes sense wrt documents loaded by the child.
 */
sync protocol PRenderFrame
{
    manager PBrowser;
    manages PLayers;

parent:
    /**
     * Shadow layer trees can be grafted into the parent's in one of
     * two ways
     *  - direct shadow tree: updates are sent to parent
     *  - indirect: the parent holds a reference (ID) to a shadow tree
     *    that's managed by the compositor.  During composition, the
     *    shadow tree is looked up and grafted appropriately
     *
     * |id| is set to 0 in the "direct" case, and to a whole number
     * in the "indirect" case.
     */
    async PLayers();

    async NotifyCompositorTransaction();

    async CancelDefaultPanZoom();

    async __delete__();

state EMPTY_OR_DIRECT_COMPOSITOR:
    recv PLayers goto HAVE_CONTENT;
    recv NotifyCompositorTransaction goto EMPTY_OR_DIRECT_COMPOSITOR;
    recv __delete__;

state HAVE_CONTENT:
    recv NotifyCompositorTransaction goto HAVE_CONTENT;
    recv __delete__;
};

} // namespace layout
} // namespace mozilla