mobile/android/bouncer/build.gradle
author Nick Alexander <nalexander@mozilla.com>
Mon, 14 Mar 2016 14:41:44 -0700
changeset 319305 a2d5576923fe2606ab7abc357c4b7c3000b6d451
parent 318821 0ce87878ee3bf6d63bd13cc03b4a9a6ca582d499
child 340011 6f87924204740088e96b5ae8e633963a90d5a359
permissions -rw-r--r--
Bug 1234629 - Post: Add Gradle support for bouncer. r=me a=sylvestre MozReview-Commit-ID: KiIs3rYit1

buildDir "${topobjdir}/gradle/build/mobile/android/bouncer"

apply plugin: 'com.android.application'

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.1"

    defaultConfig {
        targetSdkVersion 23
        minSdkVersion 15 
        applicationId mozconfig.substs.ANDROID_PACKAGE_NAME
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }
 
    dexOptions {
        javaMaxHeapSize "2g"
    }

    lintOptions {
        abortOnError false
    }

    buildTypes {
        release {
            minifyEnabled false
        }
    }

    sourceSets {
        main {
            manifest.srcFile "${topobjdir}/mobile/android/bouncer/AndroidManifest.xml"
            assets {
                if (mozconfig.substs.MOZ_ANDROID_DISTRIBUTION_DIRECTORY) {
                    srcDir "${mozconfig.substs.MOZ_ANDROID_DISTRIBUTION_DIRECTORY}/assets"
                }
            }
            java {
                srcDir 'java'
            }
            res {
                srcDir "${topsrcdir}/${mozconfig.substs.MOZ_BRANDING_DIRECTORY}/res" // For the icon.
                srcDir 'res'
            }
        }
    }
}

task generateCodeAndResources(type:Exec) {
    workingDir "${topobjdir}"

    commandLine mozconfig.substs.GMAKE
    args '-C'
    args "${topobjdir}/mobile/android/bouncer"
    args 'gradle-targets'

    // Only show the output if something went wrong.
    ignoreExitValue = true
    standardOutput = new ByteArrayOutputStream()
    errorOutput = standardOutput
    doLast {
        if (execResult.exitValue != 0) {
            throw new GradleException("Process '${commandLine}' finished with non-zero exit value ${execResult.exitValue}:\n\n${standardOutput.toString()}")
        }
    }
}

afterEvaluate {
    android.applicationVariants.all {
        preBuild.dependsOn generateCodeAndResources
    }
}