widget/cocoa/nsIdleServiceX.mm
author Ryan VanderMeulen <ryanvm@gmail.com>
Thu, 14 Aug 2014 17:23:10 -0400
changeset 222544 1d41a9159e5809e937c8abd7490dd845832652c4
parent 195406 d91f49580ec82187515b25da7578b3b8c0f4ca73
child 458550 91d647c847e56cb0db2be19647507cec207b1d08
permissions -rw-r--r--
Backed out changesets 5b1a3161f614, 17a9673ed782, and a9b8c346d295 (bug 1052052) for B2G non-unified bustage.

/* This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this
 * file, You can obtain one at http://mozilla.org/MPL/2.0/. */

#include "nsIdleServiceX.h"
#include "nsObjCExceptions.h"
#include "nsIServiceManager.h"
#import <Foundation/Foundation.h>

NS_IMPL_ISUPPORTS_INHERITED0(nsIdleServiceX, nsIdleService)

bool
nsIdleServiceX::PollIdleTime(uint32_t *aIdleTime)
{
  NS_OBJC_BEGIN_TRY_ABORT_BLOCK_RETURN;

  kern_return_t rval;
  mach_port_t masterPort;

  rval = IOMasterPort(kIOMasterPortDefault, &masterPort);
  if (rval != KERN_SUCCESS)
    return false;

  io_iterator_t hidItr;
  rval = IOServiceGetMatchingServices(masterPort,
                                      IOServiceMatching("IOHIDSystem"),
                                      &hidItr);

  if (rval != KERN_SUCCESS)
    return false;
  NS_ASSERTION(hidItr, "Our iterator is null, but it ought not to be!");

  io_registry_entry_t entry = IOIteratorNext(hidItr);
  NS_ASSERTION(entry, "Our IO Registry Entry is null, but it shouldn't be!");

  IOObjectRelease(hidItr);

  NSMutableDictionary *hidProps;
  rval = IORegistryEntryCreateCFProperties(entry,
                                           (CFMutableDictionaryRef*)&hidProps,
                                           kCFAllocatorDefault, 0);
  if (rval != KERN_SUCCESS)
    return false;
  NS_ASSERTION(hidProps, "HIDProperties is null, but no error was returned.");
  [hidProps autorelease];

  id idleObj = [hidProps objectForKey:@"HIDIdleTime"];
  NS_ASSERTION([idleObj isKindOfClass: [NSData class]] ||
               [idleObj isKindOfClass: [NSNumber class]],
               "What we got for the idle object is not what we expect!");

  uint64_t time;
  if ([idleObj isKindOfClass: [NSData class]])
    [idleObj getBytes: &time];
  else
    time = [idleObj unsignedLongLongValue];

  IOObjectRelease(entry);

  // convert to ms from ns
  time /= 1000000;
  if (time > UINT32_MAX) // Overflow will occur
    return false;

  *aIdleTime = static_cast<uint32_t>(time);

  return true;

  NS_OBJC_END_TRY_ABORT_BLOCK_RETURN(false);
}

bool
nsIdleServiceX::UsePollMode()
{
  return true;
}