dom/ipc/PTabContext.ipdlh
author Kartikaya Gupta <kgupta@mozilla.com>
Mon, 06 May 2019 22:14:40 +0000
changeset 531641 7748746bf2feda8edd0cabfdaff88b7faf059ad5
parent 531339 34023e7e4908464d5fb21ab6de63d89254ab3f36
child 536299 8d2dcfb9a9b65fefb90354d5208eef08df60a96d
permissions -rw-r--r--
Bug 1548568 - Cleanup to remove unused guid parameter in callback. r=botond Differential Revision: https://phabricator.services.mozilla.com/D29688

/* -*- Mode: C++; c-basic-offset: 4; indent-tabs-mode: nil; tab-width: 8 -*- */
/* vim: set sw=4 ts=8 et tw=80 ft=cpp : */
/* This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this
 * file, You can obtain one at http://mozilla.org/MPL/2.0/. */

include "mozilla/dom/TabMessageUtils.h";

include protocol PBrowser;
include PBrowserOrId;

using UIStateChangeType from "nsPIDOMWindow.h";
using mozilla::OriginAttributes from "mozilla/ipc/BackgroundUtils.h";

namespace mozilla {
namespace dom {

// An IPCTabContext which corresponds to a PBrowser opened by a child when it
// receives window.open().
//
// If isMozBrowserElement is false, this PopupIPCTabContext is either a
// <xul:browser> or an app frame.  The frame's app-id and app-frame-owner-app-id
// will be equal to the opener's values.
//
// It's an error to set isMozBrowserElement == false if opener is a mozbrowser
// element.  Such a PopupIPCTabContext should be rejected by code which receives
// it.
struct PopupIPCTabContext
{
  PBrowserOrId opener;
  bool isMozBrowserElement;
  uint64_t chromeOuterWindowID;
};

// An IPCTabContext which corresponds to an app, browser, or normal frame.
struct FrameIPCTabContext
{
  // The originAttributes dictionary.
  OriginAttributes originAttributes;

  // Whether this is a mozbrowser frame.  <iframe mozbrowser mozapp> and
  // <xul:browser> are not considered to be mozbrowser frames.
  bool isMozBrowserElement;

  uint64_t chromeOuterWindowID;

  // The requested presentation URL.
  // This value would be empty if the TabContext isn't created for
  // presented content.
  nsString presentationURL;

  // Keyboard indicator state inherited from the parent.
  UIStateChangeType showAccelerators;
  UIStateChangeType showFocusRings;
};

struct JSPluginFrameIPCTabContext
{
  uint32_t jsPluginId;
};

// XXXcatalinb: This is only used by ServiceWorkerClients::OpenWindow.
// Because service workers don't have an associated BrowserChild
// we can't satisfy the security constraints on b2g. As such, the parent
// process will accept this tab context only on desktop.
struct UnsafeIPCTabContext
{ };

// IPCTabContext is an analog to mozilla::dom::TabContext.  Both specify an
// iframe/PBrowser's own and containing app-ids and tell you whether the
// iframe/PBrowser is a browser frame.  But only IPCTabContext is allowed to
// travel over IPC.
//
// We need IPCTabContext (specifically, PopupIPCTabContext) to prevent a
// privilege escalation attack by a compromised child process.
union IPCTabContext
{
  PopupIPCTabContext;
  FrameIPCTabContext;
  JSPluginFrameIPCTabContext;
  UnsafeIPCTabContext;
};

}
}