dom/indexedDB/PBackgroundIDBCursor.ipdl
author Tim Nguyen <ntim.bugs@gmail.com>
Fri, 07 Jun 2019 02:00:36 +0300
changeset 533671 5ae78f2863c680529abed3a69bde02e25cafa8ee
parent 408184 f95212c33517a22afe320c0dc65e9e2f12b5080f
child 556879 d2772a7482ed9394a2c30acc6d03caa36317e75f
permissions -rw-r--r--
Bug 1551870 - Reintroduce netmonitor-toolbar-container in single-toolbar mode so React doesn't re-render the toolbar when switching panels. r=Honza a=jcristau Reviewers: Honza Reviewed By: Honza Subscribers: reviewbot Bug #: 1551870 Differential Revision: https://phabricator.services.mozilla.com/D33616

/* This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this file,
 * You can obtain one at http://mozilla.org/MPL/2.0/. */

include protocol PBackgroundIDBTransaction;
include protocol PBackgroundIDBVersionChangeTransaction;
include protocol PBackgroundMutableFile;
include protocol PChildToParentStream; // FIXME: bug 792908
include protocol PFileDescriptorSet; // FIXME: bug 792908
include protocol PIPCBlobInputStream; // FIXME: bug 792908
include protocol PParentToChildStream; // FIXME: bug 792908

include PBackgroundIDBSharedTypes;

include "mozilla/dom/indexedDB/SerializationHelpers.h";

using struct mozilla::void_t
  from "ipc/IPCMessageUtils.h";

using class mozilla::dom::indexedDB::Key
  from "mozilla/dom/indexedDB/Key.h";

namespace mozilla {
namespace dom {
namespace indexedDB {

struct ContinueParams
{
  Key key;
};

struct ContinuePrimaryKeyParams
{
  Key key;
  Key primaryKey;
};

struct AdvanceParams
{
  uint32_t count;
};

union CursorRequestParams
{
  ContinueParams;
  ContinuePrimaryKeyParams;
  AdvanceParams;
};

struct ObjectStoreCursorResponse
{
  Key key;
  SerializedStructuredCloneReadInfo cloneInfo;
};

struct ObjectStoreKeyCursorResponse
{
  Key key;
};

struct IndexCursorResponse
{
  Key key;
  Key sortKey;
  Key objectKey;
  SerializedStructuredCloneReadInfo cloneInfo;
};

struct IndexKeyCursorResponse
{
  Key key;
  Key sortKey;
  Key objectKey;
};

union CursorResponse
{
  void_t;
  nsresult;
  ObjectStoreCursorResponse[];
  ObjectStoreKeyCursorResponse;
  IndexCursorResponse;
  IndexKeyCursorResponse;
};

protocol PBackgroundIDBCursor
{
  manager PBackgroundIDBTransaction or PBackgroundIDBVersionChangeTransaction;

parent:
  async DeleteMe();

  async Continue(CursorRequestParams params);

child:
  async __delete__();

  async Response(CursorResponse response);
};

} // namespace indexedDB
} // namespace dom
} // namespace mozilla