media/webrtc/trunk/webrtc/build/util/BUILD.gn
author Daniel Varga <dvarga@mozilla.com>
Fri, 09 Nov 2018 12:22:53 +0200
changeset 445390 981eb3885ff2d2edc9408d44dab9610594a930f7
parent 444311 media/webrtc/trunk/build/util/BUILD.gn@ef27c14b46bf58f710753ae6bb6d2c01a8c3631f
parent 445272 media/webrtc/trunk/build/util/BUILD.gn@4989aa9ad7e01e986b90a86f875a23e445564ddd
permissions -rw-r--r--
Merge mozilla-central to autoland. a=merge

# Copyright (c) 2013 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

action("webkit_version") {
  script = "version.py"

  lastchange_file = "LASTCHANGE"

  template_file = "webkit_version.h.in"
  inputs = [
    lastchange_file,
    template_file,
  ]

  output_file = "$target_gen_dir/webkit_version.h"
  outputs = [
    output_file,
  ]

  args = [
    # LASTCHANGE contains "<build hash>-<ref>".  The user agent only wants the
    # "<build hash>" bit, so chop off everything after it.
    "-e",
    "LASTCHANGE=LASTCHANGE[:LASTCHANGE.find('-')]",
    "-f",
    rebase_path(lastchange_file, root_build_dir),
    rebase_path(template_file, root_build_dir),
    rebase_path(output_file, root_build_dir),
  ]
}

action("chrome_version_json") {
  script = "version.py"
  _chrome_version_path = "//chrome/VERSION"
  inputs = [
    _chrome_version_path,
  ]
  _output_file = "$root_gen_dir/CHROME_VERSION.json"
  outputs = [
    _output_file,
  ]
  args = [
    "--file",
    rebase_path(_chrome_version_path, root_build_dir),
    "--template",
    "{\"full-quoted\": \"\\\"@MAJOR@.@MINOR@.@BUILD@.@PATCH@\\\"\"}",
    "--output",
    rebase_path(_output_file, root_build_dir),
  ]
}