modules/releaserunner3/manifests/init.pp
author Aki Sasaki <asasaki@mozilla.com>
Mon, 22 Jan 2018 19:37:45 -0800
changeset 6096 bd4d3f30787c0afc56f87f6c0b9367595312a31b
parent 5923 9b340e5acad9d57c89eb7152202a58ede2102b9d
child 6257 2c7dc41e90def6f7817b9fc6afa4a12bfbcea104
permissions -rw-r--r--
bug 1432364 - rr3 should use json-e==2.5.0. r=mtabara MozReview-Commit-ID: KwMn6ukq9Ur

# This Source Code Form is subject to the terms of the Mozilla Public
# License, v. 2.0. If a copy of the MPL was not distributed with this
# file, You can obtain one at http://mozilla.org/MPL/2.0/.

class releaserunner3 {
    include ::config
    include dirs::builds
    include users::builder
    include packages::gcc
    include releaserunner3::settings
    include releaserunner3::services
    include packages::mozilla::python27

    $env_config = $config::releaserunner3_env_config[$releaserunner3_env]

    python::virtualenv {
        $releaserunner3::settings::root:
            python   => $packages::mozilla::python27::python,
            require  => [
                Class['packages::mozilla::python27'],
            ],
            user     => $users::builder::username,
            group    => $users::builder::group,
            packages => [
                'PyYAML==3.12',
                'Twisted==12.3.0',
                'certifi==2017.07.27.1',
                'chardet==3.0.4',
                'idna==2.6',
                'json-e==2.5.0',
                'mohawk==0.3.4',
                'requests==2.18.4',
                'simplejson==3.11.1',
                'six==1.11.0',
                'slugid==1.0.7',
                'taskcluster==1.3.5',
                'urllib3==1.22',
                'wsgiref==0.1.2',
                'zope.interface==4.4.3',
            ];
    }

    file {
        "${releaserunner3::settings::root}/release-runner.yml":
            require   => Python::Virtualenv[$releaserunner3::settings::root],
            mode      => '0600',
            owner     => $users::builder::username,
            group     => $users::builder::group,
            content   => template('releaserunner3/release-runner.yml.erb'),
            show_diff => false;
    }

    mercurial::repo {
        'releaserunner3-tools':
            require => Python::Virtualenv[$releaserunner3::settings::root],
            hg_repo => $config::releaserunner_tools,
            dst_dir => $releaserunner3::settings::tools_dst,
            user    => $users::builder::username,
            branch  => $config::releaserunner_tools_branch,
    }
}